Library mcertikos.proc.PIPC

***********************************************************************
*                                                                     *
*            The CertiKOS Certified Kit Operating System              *
*                                                                     *
*                   The FLINT Group, Yale University                  *
*                                                                     *
*  Copyright The FLINT Group, Yale University.  All rights reserved.  *
*  This file is distributed under the terms of the Yale University    *
*  Non-Commercial License Agreement.                                  *
*                                                                     *
***********************************************************************


This file defines the abstract data and the primitives for the PIPC layer, which will introduce the primtives of thread
Require Import Coqlib.
Require Import Maps.
Require Import ASTExtra.
Require Import Integers.
Require Import Floats.
Require Import Values.
Require Import Memory.
Require Import Events.
Require Import Stacklayout.
Require Import Globalenvs.
Require Import AsmX.
Require Import Smallstep.
Require Import AuxStateDataType.
Require Import Constant.
Require Import GlobIdent.
Require Import FlatMemory.
Require Import CommonTactic.
Require Import AuxLemma.
Require Import RealParams.
Require Import PrimSemantics.
Require Import LAsm.
Require Import LoadStoreSem2.
Require Import XOmega.

Require Import liblayers.logic.PTreeModules.
Require Import liblayers.logic.LayerLogicImpl.
Require Import liblayers.compat.CompatLayers.
Require Import liblayers.compat.CompatGenSem.

Require Import CalRealPTPool.
Require Import CalRealPT.
Require Import CalRealIDPDE.
Require Import CalRealInitPTE.
Require Import CalRealPTB.
Require Import CalRealSMSPool.
Require Import CalRealProcModule.

Require Import INVLemmaContainer.
Require Import INVLemmaMemory.
Require Import INVLemmaThread.
Require Import INVLemmaProc.

Require Import AbstractDataType.
Require Import DeviceStateDataType.

Require Export ObjCPU.
Require Export ObjFlatMem.
Require Export ObjContainer.
Require Export ObjVMM.
Require Export ObjLMM.
Require Export ObjShareMem.
Require Export ObjThread.
Require Export ObjProc.
Require Export ObjSyncIPC.
Require Export ObjInterruptController.
Require Export ObjInterruptManagement.
Require Export ObjConsole.
Require Export ObjSerialDriver.

Abstract Data and Primitives at this layer

Section WITHMEM.

  Local Open Scope Z_scope.

  Context `{real_params: RealParams}.

**Definition of the invariants at MPTNew layer 0th page map is reserved for the kernel thread
  Record high_level_invariant (abd: RData) :=
    mkInvariant {
        valid_nps: pg abd = true → kern_low ≤ nps abd ≤ maxpage;
        valid_AT_kern: pg abd = true → LAT_kern (LAT abd) (nps abd);
        valid_AT_usr: pg abd = true → LAT_usr (LAT abd) (nps abd);
        valid_kern: ipt abd = false → pg abd = true;
        valid_iptt: ipt abd = true → ikern abd = true;
        valid_iptf: ikern abd = false → ipt abd = false;
        valid_ihost: ihost abd = false → pg abd = true ∧ ikern abd = true;
        valid_container: Container_valid (AC abd);
        valid_pperm_ppage: Lconsistent_ppage (LAT abd) (pperm abd) (nps abd);
        init_pperm: pg abd = false → (pperm abd) = ZMap.init PGUndef;
        valid_PMap: pg abd = true →
                    (∀ i, 0≤ i < num_proc →
                               PMap_valid (ZMap.get i (ptpool abd)));
        
        valid_PT_kern: pg abd = true → ipt abd = true → (PT abd) = 0;
        valid_PMap_kern: pg abd = true → PMap_kern (ZMap.get 0 (ptpool abd));
        valid_PT: pg abd = true → 0≤ PT abd < num_proc;
        valid_dirty: dirty_ppage (pperm abd) (HP abd);

        valid_idpde: pg abd = true → IDPDE_init (idpde abd);
        valid_pperm_pmap: consistent_pmap (ptpool abd) (pperm abd) (LAT abd) (nps abd);
        valid_pmap_domain: consistent_pmap_domain (ptpool abd) (pperm abd) (LAT abd) (nps abd);
        valid_lat_domain: consistent_lat_domain (ptpool abd) (LAT abd) (nps abd);

        valid_PTB: pg abd = true → (ZMap.get 0 (pb abd)) = PTTrue;
        valid_PTBR: pg abd = true → PTB_defined (pb abd) 0 num_proc;
        valid_PTB_AC:
          ∀ i, 0 ≤ i < num_id →
                    (ZMap.get i (pb abd) = PTTrue ↔ cused (ZMap.get i (AC abd)) = true);
        valid_cons_buf_rpos: 0 ≤ rpos (console abd) < CONSOLE_BUFFER_SIZE;
        valid_cons_buf_length: 0 ≤ Zlength (cons_buf (console abd)) < CONSOLE_BUFFER_SIZE;
        
        valid_TCB: pg abd = true → AbTCBStrong_range (abtcb abd);
        valid_TDQ: pg abd = true → AbQCorrect_range (abq abd);
        valid_notinQ: pg abd = true → NotInQ (pb abd) (abtcb abd);
        valid_count: pg abd = true → QCount (abtcb abd) (abq abd);
        valid_inQ: pg abd = true → InQ (abtcb abd) (abq abd);
        valid_curid: 0 ≤ cid abd < num_proc;
        correct_curid: pg abd = true → CurIDValid (cid abd) (pb abd) (abtcb abd);
        single_curid: pg abd = true → SingleRun (cid abd) (abtcb abd);
        
        valid_chan: pg abd = true → SyncChanPool_Valid (syncchpool abd)
      }.

Definition of the abstract state ops

  Global Instance pipc_data_ops : CompatDataOps RData :=
    {
      empty_data := init_adt;
      high_level_invariant := high_level_invariant;
      low_level_invariant := low_level_invariant;
      kernel_mode adt := ikern adt = true ∧ ihost adt = true
    }.

Proofs that the initial abstract_data should satisfy the invariants

  Section Property_Abstract_Data.

    Lemma empty_data_high_level_invariant:
      high_level_invariant init_adt.
    Proof.
      constructor; simpl; intros; auto; try inv H.
      - apply empty_container_valid.
      - eapply Lconsistent_ppage_init.
      - eapply dirty_ppage_init.
      - eapply consistent_pmap_init.
      - eapply consistent_pmap_domain_init.
      - eapply consistent_lat_domain_init.
      - repeat rewrite ZMap.gi; intuition.
      - omega.
      - rewrite Zlength_nil; omega.
      - omega.
    Qed.

Definition of the abstract state

    Global Instance pipc_data_prf : CompatData RData.
    Proof.
      constructor.
      - apply low_level_invariant_incr.
      - apply empty_data_low_level_invariant.
      - apply empty_data_high_level_invariant.
    Qed.

  End Property_Abstract_Data.

  Context `{Hstencil: Stencil}.
  Context `{Hmem: Mem.MemoryModel}.
  Context `{Hmwd: UseMemWithData mem}.

Proofs that the primitives satisfies the invariants at this layer

  Section INV.

    Section PALLOC.

      Lemma palloc_high_level_inv:
        ∀ d d´ i n,
          palloc_spec i d = Some (d´, n) →
          high_level_invariant d →
          high_level_invariant d´.
      Proof.
        intros. functional inversion H; subst; eauto.
        inv H0. constructor; simpl; eauto.
        - intros; eapply LAT_kern_norm; eauto. eapply _x.
        - intros; eapply LAT_usr_norm; eauto.
        - eapply alloc_container_valid´; eauto.
        - eapply Lconsistent_ppage_norm_alloc; eauto.
        - intros; congruence.
        - eapply dirty_ppage_gso_alloc; eauto.
        - eapply consistent_pmap_gso_at_false; eauto. apply _x.
        - eapply consistent_pmap_domain_gso_at_false; eauto. apply _x.
        - eapply consistent_lat_domain_gss_nil; eauto.
        - subst cur c; intros; eapply container_alloc_PTB_AC_valid; eauto.
      Qed.

      Lemma palloc_low_level_inv:
        ∀ d d´ i n n´,
          palloc_spec i d = Some (d´, n) →
          low_level_invariant n´ d →
          low_level_invariant n´ d´.
      Proof.
        intros. functional inversion H; subst; eauto.
        inv H0. constructor; eauto.
      Qed.

      Lemma palloc_kernel_mode:
        ∀ d d´ i n,
          palloc_spec i d = Some (d´, n) →
          kernel_mode d →
          kernel_mode d´.
      Proof.
        intros. functional inversion H; subst; eauto.
      Qed.

      Global Instance palloc_inv: PreservesInvariants palloc_spec.
      Proof.
        preserves_invariants_simpl´.
        - eapply palloc_low_level_inv; eassumption.
        - eapply palloc_high_level_inv; eassumption.
        - eapply palloc_kernel_mode; eassumption.
      Qed.

    End PALLOC.

    Global Instance pfree_inv: PreservesInvariants pfree_spec.
    Proof.
      preserves_invariants_simpl low_level_invariant high_level_invariant; eauto 2.
      - intros; eapply LAT_kern_norm; eauto.
      - intros; eapply LAT_usr_norm; eauto.
      - eapply Lconsistent_ppage_norm_undef; eauto.
      - eapply dirty_ppage_gso_undef; eauto.
      - eapply consistent_pmap_gso_pperm_alloc; eauto.
      - eapply consistent_pmap_domain_gso_at_0; eauto.
      - eapply consistent_lat_domain_gss_nil; eauto.
    Qed.

    Global Instance trapin_inv: PrimInvariants trapin_spec.
    Proof.
      PrimInvariants_simpl H H0.
    Qed.

    Global Instance trapout_inv: PrimInvariants trapout_spec.
    Proof.
      PrimInvariants_simpl H H0.
    Qed.

    Global Instance hostin_inv: PrimInvariants hostin_spec.
    Proof.
      PrimInvariants_simpl H H0.
    Qed.

    Global Instance hostout_inv: PrimInvariants hostout_spec.
    Proof.
      PrimInvariants_simpl H H0.
    Qed.

    Global Instance ptin_inv: PrimInvariants ptin_spec.
    Proof.
      PrimInvariants_simpl H H0.
    Qed.

    Global Instance ptout_inv: PrimInvariants ptout_spec.
    Proof.
      PrimInvariants_simpl H H0.
    Qed.

    Global Instance fstore_inv: PreservesInvariants fstore_spec.
    Proof.
      split; intros; inv_generic_sem H; inv H0; functional inversion H2.
      - functional inversion H. split; trivial.
      - functional inversion H.
        split; subst; simpl;
        try (eapply dirty_ppage_store_unmaped; try reflexivity; try eassumption); trivial.
      - functional inversion H0.
        split; simpl; try assumption.
    Qed.

    Global Instance setPT_inv: PreservesInvariants setPT_spec.
    Proof.
      preserves_invariants_simpl low_level_invariant high_level_invariant; eauto 2.
    Qed.

    Section PTINSERT.

      Section PTINSERT_PTE.

        Lemma ptInsertPTE_high_level_inv:
          ∀ d d´ n vadr padr p,
            ptInsertPTE0_spec n vadr padr p d = Some d´ →
            high_level_invariant d →
            high_level_invariant d´.
        Proof.
          intros. functional inversion H; subst; eauto.
          inv H0; constructor_gso_simpl_tac; intros.
          - eapply LAT_kern_norm; eauto.
          - eapply LAT_usr_norm; eauto.
          - eapply Lconsistent_ppage_norm; eassumption.
          - eapply PMap_valid_gso_valid; eauto.
          - functional inversion H2. functional inversion H1.
            eapply PMap_kern_gso; eauto.
          - functional inversion H2. functional inversion H0.
            eapply consistent_pmap_ptp_same; try eassumption.
            eapply consistent_pmap_gso_pperm_alloc´; eassumption.
          - functional inversion H2.
            eapply consistent_pmap_domain_append; eauto.
            destruct (ZMap.get pti pdt); try contradiction;
            red; intros (v0 & p0 & He); contra_inv.
          - eapply consistent_lat_domain_gss_append; eauto.
            subst pti; destruct (ZMap.get (PTX vadr) pdt); try contradiction;
            red; intros (v0 & p0 & He); contra_inv.
        Qed.

        Lemma ptInsertPTE_low_level_inv:
          ∀ d d´ n vadr padr p n´,
            ptInsertPTE0_spec n vadr padr p d = Some d´ →
            low_level_invariant n´ d →
            low_level_invariant n´ d´.
        Proof.
          intros. functional inversion H; subst; eauto.
          inv H0. constructor; eauto.
        Qed.

        Lemma ptInsertPTE_kernel_mode:
          ∀ d d´ n vadr padr p,
            ptInsertPTE0_spec n vadr padr p d = Some d´ →
            kernel_mode d →
            kernel_mode d´.
        Proof.
          intros. functional inversion H; subst; eauto.
        Qed.

      End PTINSERT_PTE.

      Section PTPALLOCPDE.

        Lemma ptAllocPDE_high_level_inv:
          ∀ d d´ n vadr v,
            ptAllocPDE0_spec n vadr d = Some (d´, v) →
            high_level_invariant d →
            high_level_invariant d´.
        Proof.
          intros. functional inversion H; subst; eauto.
          inv H0; constructor_gso_simpl_tac; intros.
          - eapply LAT_kern_norm; eauto. eapply _x.
          - eapply LAT_usr_norm; eauto.
          - eapply alloc_container_valid´; eauto.
          - apply Lconsistent_ppage_norm_hide; try assumption.
          - congruence.
          - eapply PMap_valid_gso_pde_unp; eauto.
            eapply real_init_PTE_defined.
          - functional inversion H3.
            eapply PMap_kern_gso; eauto.
          - eapply dirty_ppage_gss; eauto.
          - eapply consistent_pmap_ptp_gss; eauto; apply _x.
          - eapply consistent_pmap_domain_gso_at_false; eauto; try apply _x.
            eapply consistent_pmap_domain_ptp_unp; eauto.
            apply real_init_PTE_unp.
          - apply consistent_lat_domain_gss_nil; eauto.
            apply consistent_lat_domain_gso_p; eauto.
          - subst cur c; eapply container_alloc_PTB_AC_valid; eauto.
        Qed.

        Lemma ptAllocPDE_low_level_inv:
          ∀ d d´ n vadr v n´,
            ptAllocPDE0_spec n vadr d = Some (d´, v) →
            low_level_invariant n´ d →
            low_level_invariant n´ d´.
        Proof.
          intros. functional inversion H; subst; eauto.
          inv H0. constructor; eauto.
        Qed.

        Lemma ptAllocPDE_kernel_mode:
          ∀ d d´ n vadr v,
            ptAllocPDE0_spec n vadr d = Some (d´, v) →
            kernel_mode d →
            kernel_mode d´.
        Proof.
          intros. functional inversion H; subst; eauto.
        Qed.

      End PTPALLOCPDE.

      Lemma ptInsert_high_level_inv:
        ∀ d d´ n vadr padr p v,
          ptInsert0_spec n vadr padr p d = Some (d´, v) →
          high_level_invariant d →
          high_level_invariant d´.
      Proof.
        intros. functional inversion H; subst; eauto.
        - eapply ptInsertPTE_high_level_inv; eassumption.
        - eapply ptAllocPDE_high_level_inv; eassumption.
        - eapply ptInsertPTE_high_level_inv; try eassumption.
          eapply ptAllocPDE_high_level_inv; eassumption.
      Qed.

      Lemma ptInsert_low_level_inv:
        ∀ d d´ n vadr padr p n´ v,
          ptInsert0_spec n vadr padr p d = Some (d´, v) →
          low_level_invariant n´ d →
          low_level_invariant n´ d´.
      Proof.
        intros. functional inversion H; subst; eauto.
        - eapply ptInsertPTE_low_level_inv; eassumption.
        - eapply ptAllocPDE_low_level_inv; eassumption.
        - eapply ptInsertPTE_low_level_inv; try eassumption.
          eapply ptAllocPDE_low_level_inv; eassumption.
      Qed.

      Lemma ptInsert_kernel_mode:
        ∀ d d´ n vadr padr p v,
          ptInsert0_spec n vadr padr p d = Some (d´, v) →
          kernel_mode d →
          kernel_mode d´.
      Proof.
        intros. functional inversion H; subst; eauto.
        - eapply ptInsertPTE_kernel_mode; eassumption.
        - eapply ptAllocPDE_kernel_mode; eassumption.
        - eapply ptInsertPTE_kernel_mode; try eassumption.
          eapply ptAllocPDE_kernel_mode; eassumption.
      Qed.

    End PTINSERT.

    Section PTRESV.

      Lemma ptResv_high_level_inv:
        ∀ d d´ n vadr p v,
          ptResv_spec n vadr p d = Some (d´, v) →
          high_level_invariant d →
          high_level_invariant d´.
      Proof.
        intros. functional inversion H; subst; eauto.
        eapply ptInsert_high_level_inv; try eassumption.
        eapply palloc_high_level_inv; eassumption.
      Qed.

      Lemma ptResv_low_level_inv:
        ∀ d d´ n vadr p n´ v,
          ptResv_spec n vadr p d = Some (d´, v) →
          low_level_invariant n´ d →
          low_level_invariant n´ d´.
      Proof.
        intros. functional inversion H; subst; eauto.
        eapply ptInsert_low_level_inv; try eassumption.
        eapply palloc_low_level_inv; eassumption.
      Qed.

      Lemma ptResv_kernel_mode:
        ∀ d d´ n vadr p v,
          ptResv_spec n vadr p d = Some (d´, v) →
          kernel_mode d →
          kernel_mode d´.
      Proof.
        intros. functional inversion H; subst; eauto.
        eapply ptInsert_kernel_mode; try eassumption.
        eapply palloc_kernel_mode; eassumption.
      Qed.

      Global Instance ptResv_inv: PreservesInvariants ptResv_spec.
      Proof.
        preserves_invariants_simpl´.
        - eapply ptResv_low_level_inv; eassumption.
        - eapply ptResv_high_level_inv; eassumption.
        - eapply ptResv_kernel_mode; eassumption.
      Qed.

    End PTRESV.

    Section OFFER_SHARE.

      Section PTRESV2.

        Lemma ptResv2_high_level_inv:
          ∀ d d´ n vadr p n´ vadr´ p´ v,
            ptResv2_spec n vadr p n´ vadr´ p´ d = Some (d´, v) →
            high_level_invariant d →
            high_level_invariant d´.
        Proof.
          intros; functional inversion H; subst; eauto;
          eapply ptInsert_high_level_inv; try eassumption.
          - eapply palloc_high_level_inv; eassumption.
          - eapply ptInsert_high_level_inv; try eassumption.
            eapply palloc_high_level_inv; eassumption.
        Qed.

        Lemma ptResv2_low_level_inv:
          ∀ d d´ n vadr p n´ vadr´ p´ l v,
            ptResv2_spec n vadr p n´ vadr´ p´ d = Some (d´, v) →
            low_level_invariant l d →
            low_level_invariant l d´.
        Proof.
          intros; functional inversion H; subst; eauto;
          eapply ptInsert_low_level_inv; try eassumption.
          - eapply palloc_low_level_inv; eassumption.
          - eapply ptInsert_low_level_inv; try eassumption.
            eapply palloc_low_level_inv; eassumption.
        Qed.

        Lemma ptResv2_kernel_mode:
          ∀ d d´ n vadr p n´ vadr´ p´ v,
            ptResv2_spec n vadr p n´ vadr´ p´ d = Some (d´, v) →
            kernel_mode d →
            kernel_mode d´.
        Proof.
          intros; functional inversion H; subst; eauto;
          eapply ptInsert_kernel_mode; try eassumption.
          - eapply palloc_kernel_mode; eassumption.
          - eapply ptInsert_kernel_mode; try eassumption.
            eapply palloc_kernel_mode; eassumption.
        Qed.

      End PTRESV2.

      Global Instance offer_shared_mem_inv:
        PreservesInvariants offer_shared_mem_spec.
      Proof.
        preserves_invariants_simpl´;
        functional inversion H2; subst; eauto 2; try (inv H0; constructor; trivial; fail).
        - exploit ptResv2_low_level_inv; eauto.
          intros HP; inv HP. constructor; trivial.
        - exploit ptResv2_low_level_inv; eauto.
          intros HP; inv HP. constructor; trivial.
        - exploit ptResv2_high_level_inv; eauto.
          intros HP; inv HP. constructor; trivial.
        - exploit ptResv2_high_level_inv; eauto.
          intros HP; inv HP. constructor; trivial.
        - exploit ptResv2_kernel_mode; eauto.
        - exploit ptResv2_kernel_mode; eauto.
      Qed.

    End OFFER_SHARE.

    Global Instance shared_mem_status_inv:
      PreservesInvariants shared_mem_status_spec.
    Proof.
      preserves_invariants_simpl low_level_invariant high_level_invariant; eauto 2.
    Qed.

    Global Instance thread_spawn_inv: DNewInvariants thread_spawn_spec.
    Proof.
      constructor; intros; inv H0;
      unfold thread_spawn_spec in *;
      subdestruct; inv H; simpl; auto.

      -
        constructor; trivial; intros; simpl in ×.
        eapply kctxt_inject_neutral_gss_flatinj´; eauto.
        eapply kctxt_inject_neutral_gss_flatinj; eauto.

      -
        constructor; simpl; eauto 2; try congruence; intros.
        + exploit split_container_valid; eauto.
          assert (Htmp:= a0); decompose [and] Htmp; eapply container_split_some´; eauto.
          auto.
        + eapply ptb_true_set_true; eauto.
        + eapply PTB_defined_defined_true; eauto.
        + eapply container_split_PTB_AC_valid´; eauto.
        + eapply AbTCBStrong_range_gss_READY; eauto.
        + eapply AbQCorrect_range_gss_enqueue; eauto. omega.
        + eapply NotInQ_gso_pb_PTTrue; eauto.
        + eapply QCount_gss_spawn; eauto.
          eapply AbTCBStrong_range_impl; eauto.
        + eapply InQ_gss_spawn; eauto.
          eapply AbTCBStrong_range_impl; eauto.
        + eapply CurIDValid_gso_neq_PTTrue; eauto. apply a0.
        + eapply SingleRun_gso_state_READY; eauto.
    Qed.

    Local Opaque remove.

    Global Instance thread_yield_inv: ThreadScheduleInvariants thread_yield_spec.
    Proof.
      constructor; intros; functional inversion H.
      - inv H1. constructor; trivial.
        eapply kctxt_inject_neutral_gss_mem; eauto.
      - inv H0. subst.
        assert (HOS: 0≤ num_chan ≤ num_chan) by omega.
        exploit last_range_AbQ; eauto. intros Hrange.
        constructor; auto; simpl in *; intros; try congruence.
        + eapply AbTCBStrong_range_gss_RUN; eauto.
          eapply AbTCBStrong_range_gss_READY; eauto.
        + eapply AbQCorrect_range_gss_remove´; eauto.
          eapply list_range_enqueue; eauto.
          eapply AbQCorrect_range_impl; eauto.
        + eapply NotInQ_gso_neg; eauto.
          eapply NotInQ_gso_pb; eauto.
          eapply correct_curid0; eauto.
        + eapply QCount_gss_yield; eauto.
        + eapply InQ_gss_yield; eauto.
        + eapply CurIDValid_gss_last; eauto.
        + eapply SingleRun_gss_gso_cid; eauto. congruence.
    Qed.

    Global Instance thread_sleep_inv: ThreadTransferInvariants thread_sleep_spec.
    Proof.
      constructor; intros; functional inversion H.
      - inv H1. constructor; trivial.
        eapply kctxt_inject_neutral_gss_mem; eauto.
      - inv H0. subst.
        assert (HOS: 0≤ num_chan ≤ num_chan) by omega.
        assert (HNeq: 64 ≠ n´) by omega.
        exploit last_range_AbQ; eauto. intros Hrange.
        assert (HOS´: 0 ≤ n´ ≤ num_proc) by omega.
        assert (Hcid: ZMap.get (cid d) (abtcb d) = AbTCBValid RUN (-1))
          by (eapply correct_curid0; eauto).
        constructor; auto; simpl in *; intros; try congruence.
        + eapply AbTCBStrong_range_gss_RUN; eauto.
          eapply AbTCBStrong_range_gss_SLEEP; eauto.
        + eapply AbQCorrect_range_gss_remove; eauto.
          × eapply AbQCorrect_range_gss_enqueue; eauto.
          × rewrite ZMap.gso; eauto.
        + eapply NotInQ_gso_neg; eauto.
          eapply NotInQ_gso_pb; eauto.
          eapply correct_curid0; eauto.
        + eapply QCount_gss_remove; eauto.
          × eapply QCount_gss_enqueue; eauto.
          × rewrite ZMap.gso; eauto.
        + eapply InQ_gss_remove; eauto.
          × eapply InQ_gss_enqueue; eauto.
          × eapply QCount_gss_enqueue; eauto.
          × rewrite ZMap.gso; eauto.
          × apply last_correct; eauto.
        + eapply CurIDValid_gss_last; eauto.
        + eapply SingleRun_gss_gso_cid; eauto. congruence.
    Qed.


    Section THREAD_WAKEUP.

      Lemma thread_wakeup_high_level_inv:
        ∀ d d´ n,
          thread_wakeup_spec n d = Some d´ →
          high_level_invariant d →
          high_level_invariant d´.
      Proof.
        intros. functional inversion H; subst; eauto.
        inv H0. constructor; simpl; eauto; intros.
        - eapply AbTCBStrong_range_gss_READY; eauto.
        - eapply AbQCorrect_range_gss_wakeup; eauto.
        - clear valid_curid0. eapply NotInQ_InQ_gss_wakeup; eauto.
        - eapply QCount_gss_wakeup; eauto.
        - eapply InQ_gss_wakeup; eauto.
        - eapply CurIDValid_gso_tcb; eauto.
          eapply last_neq_cid; eauto. omega.
        - eapply SingleRun_gso_state_READY; eauto.
      Qed.

      Lemma thread_wakeup_low_level_inv:
        ∀ d d´ n n´,
          thread_wakeup_spec n d = Some d´ →
          low_level_invariant n´ d →
          low_level_invariant n´ d´.
      Proof.
        intros. functional inversion H; subst; eauto.
        inv H0. constructor; eauto.
      Qed.

      Lemma thread_wakeup_kernel_mode:
        ∀ d d´ n,
          thread_wakeup_spec n d = Some d´ →
          kernel_mode d →
          kernel_mode d´.
      Proof.
        intros. functional inversion H; subst; eauto.
      Qed.

      Global Instance thread_wakeup_inv: PreservesInvariants thread_wakeup_spec.
      Proof.
        preserves_invariants_simpl´.
        - eapply thread_wakeup_low_level_inv; eassumption.
        - eapply thread_wakeup_high_level_inv; eassumption.
        - eapply thread_wakeup_kernel_mode; eassumption.
      Qed.

    End THREAD_WAKEUP.


    Global Instance syncsendto_chan_pre_inv: PreservesInvariants syncsendto_chan_pre_spec.
    Proof.
      preserves_invariants_simpl low_level_invariant high_level_invariant; eauto 2.
      eapply SyncChanPool_Valid_gss; eauto.
    Qed.

    Global Instance syncsendto_chan_post_inv: PreservesInvariants syncsendto_chan_post_spec.
    Proof.
      preserves_invariants_simpl low_level_invariant high_level_invariant; eauto 2.
      eapply SyncChanPool_Valid_gss; eauto.
    Qed.

    Section MEMCPY.

      Lemma flatmem_copy_high_level_inv:
        ∀ d d´ from to len,
          flatmem_copy_spec len to from d = Some d´
          → high_level_invariant d
          → high_level_invariant d´.
      Proof.
        intros. functional inversion H; subst; eauto.
        inv H0.
        constructor; simpl; intros;
        try eapply dirty_ppage_gss_copy; eauto.
      Qed.

      Lemma flatmem_copy_low_level_inv:
        ∀ d d´ from to len n,
          flatmem_copy_spec len to from d = Some d´
          → low_level_invariant n d
          → low_level_invariant n d´.
      Proof.
        intros. functional inversion H; subst; eauto.
        inv H0. constructor; eauto 2.
      Qed.

      Lemma flatmem_copy_kernel_mode:
        ∀ d d´ from to len,
          flatmem_copy_spec len to from d = Some d´
          → kernel_mode d
          → kernel_mode d´.
      Proof.
        intros. functional inversion H; subst; eauto.
      Qed.

    End MEMCPY.

    Section SYNCRECEIVE_CHAN.

      Lemma syncreceive_chan_high_level_inv:
        ∀ fromid vaddr count d d´ n,
          syncreceive_chan_spec fromid vaddr count d = Some (d´, n) →
          high_level_invariant d →
          high_level_invariant d´.
      Proof.
        intros. functional inversion H; subst; eauto.
        exploit thread_wakeup_high_level_inv; eauto.
        exploit flatmem_copy_high_level_inv; eauto.
        intros Hh. inv Hh. constructor; eauto 2; simpl; intros.
        eapply SyncChanPool_Valid_gss; eauto.
      Qed.

      Lemma syncreceive_chan_low_level_inv:
        ∀ fromid vaddr count d d´ n n´,
          syncreceive_chan_spec fromid vaddr count d = Some (d´, n) →
          low_level_invariant n´ d →
          low_level_invariant n´ d´.
      Proof.
        intros. functional inversion H; subst; eauto.
        exploit thread_wakeup_low_level_inv; eauto.
        exploit flatmem_copy_low_level_inv; eauto.
        intros Hh. inv Hh. constructor; eauto 2.
      Qed.

      Lemma syncreceive_chan_kernel_mode:
        ∀ fromid vaddr count d d´ n,
          syncreceive_chan_spec fromid vaddr count d = Some (d´, n) →
          kernel_mode d →
          kernel_mode d´.
      Proof.
        intros. functional inversion H; subst; eauto.
        exploit thread_wakeup_kernel_mode; eauto.
        exploit flatmem_copy_kernel_mode; eauto.
      Qed.

      Global Instance syncreceive_chan_inv: PreservesInvariants syncreceive_chan_spec.
      Proof.
        preserves_invariants_simpl´.
        - eapply syncreceive_chan_low_level_inv; eassumption.
        - eapply syncreceive_chan_high_level_inv; eassumption.
        - eapply syncreceive_chan_kernel_mode; eassumption.
      Qed.

    End SYNCRECEIVE_CHAN.

    Global Instance proc_init_inv: PreservesInvariants proc_init_spec.
    Proof.
      preserves_invariants_simpl low_level_invariant high_level_invariant.
      - apply real_nps_range.
      - apply real_lat_kern_valid.
      - apply real_lat_usr_valid.
      - apply AC_init_container_valid.
      - rewrite init_pperm0; try assumption.
        apply Lreal_pperm_valid.
      - eapply real_pt_PMap_valid; eauto.
      - apply real_pt_PMap_kern.
      - omega.
      - assumption.
      - apply real_idpde_init.
      - apply real_pt_consistent_pmap.
      - apply real_pt_consistent_pmap_domain.
      - apply Lreal_at_consistent_lat_domain.
      - apply real_PTB_0_valid.
      - apply real_PTB_valid.
      - eapply real_PTB_AC_valid; eauto.
      - apply real_abtcb_strong_range´; eauto.
      - apply real_abq_range; auto.
      - eapply real_abtcb_pb_notInQ´; eauto.
      - eapply real_abtcb_abq_QCount´; eauto.
      - eapply real_abq_tcb_inQ; eauto.
      - omega.
      - eapply real_abtcb_PTB_CurIDValid; eauto.
      - eapply real_abtcb_SingleRun; eauto.
      - eapply real_syncchpool_valid´; eauto.
    Qed.

device primitives
    Require Import FutureTactic.
    Require Export ObjInterruptController.
    Global Instance cli_inv: PreservesInvariants cli_spec.
    Proof.
      preserves_invariants_direct low_level_invariant high_level_invariant; eauto 2.
    Qed.

    Global Instance sti_inv: PreservesInvariants sti_spec.
    Proof.
      preserves_invariants_direct low_level_invariant high_level_invariant; eauto 2.
    Qed.

    Require Export ObjConsole.
    Require Import INVLemmaDriver.
    Global Instance cons_buf_read_inv:
      PreservesInvariants cons_buf_read_spec.
    Proof.
      preserves_invariants_nested low_level_invariant high_level_invariant; eauto 2.
    Qed.

    Require Export ObjSerialDriver.
    Global Instance serial_putc_inv:
      PreservesInvariants serial_putc_spec.
    Proof.
      preserves_invariants_simpl low_level_invariant high_level_invariant; eauto 2.
    Qed.

    Require Export ObjInterruptManagement.
    Require Import INVLemmaInterrupt.

    Global Instance serial_intr_disable_inv: PreservesInvariants serial_intr_disable_spec.
    Proof.
      constructor; simpl; intros; inv_generic_sem H;
      inversion H0; econstructor; generalize (serial_intr_disable_preserves_all d d´ H2);
      intros Hpre; blast Hpre; eauto 2 with serial_intr_disable_invariantdb.
    Qed.

    Global Instance serial_intr_enable_inv: PreservesInvariants serial_intr_enable_spec.
    Proof.
      constructor; simpl; intros; inv_generic_sem H;
      inversion H0; econstructor; generalize (serial_intr_enable_preserves_all d d´ H2);
      intros Hpre; blast Hpre; eauto 2 with serial_intr_enable_invariantdb.
    Qed.

  End INV.

  Definition exec_loadex {F V} := exec_loadex2 (F := F) (V := V).

  Definition exec_storeex {F V} := exec_storeex2 (flatmem_store:= flatmem_store) (F := F) (V := V).

  Global Instance flatmem_store_inv: FlatmemStoreInvariant (flatmem_store:= flatmem_store).
  Proof.
    split; inversion 1; intros.
    - functional inversion H0. split; trivial.
    - functional inversion H1.
      split; simpl; try (eapply dirty_ppage_store_unmaped´; try reflexivity; try eassumption); trivial.
  Qed.

  Global Instance trapinfo_set_inv: TrapinfoSetInvariant.
  Proof.
    split; inversion 1; intros; constructor; auto.
  Qed.

Layer Definition

  Definition pipc_fresh : compatlayer (cdata RData) :=
    syncreceive_chan ↦ gensem syncreceive_chan_spec
                  ⊕ syncsendto_chan_pre ↦ gensem syncsendto_chan_pre_spec
                  ⊕ syncsendto_chan_post ↦ gensem syncsendto_chan_post_spec
                  ⊕ proc_init ↦ gensem proc_init_spec.

  Definition pipc_passthrough : compatlayer (cdata RData) :=
    fload ↦ gensem fload_spec
          ⊕ fstore ↦ gensem fstore_spec
          ⊕ vmxinfo_get ↦ gensem vmxinfo_get_spec
          ⊕ palloc ↦ gensem palloc_spec
          ⊕ pfree ↦ gensem pfree_spec
          ⊕ set_pt ↦ gensem setPT_spec
          ⊕ pt_read ↦ gensem ptRead_spec
          ⊕ pt_resv ↦ gensem ptResv_spec
          ⊕ shared_mem_status ↦ gensem shared_mem_status_spec
          ⊕ offer_shared_mem ↦ gensem offer_shared_mem_spec

          ⊕ get_curid ↦ gensem get_curid_spec
          ⊕ thread_spawn ↦ dnew_compatsem thread_spawn_spec
          ⊕ thread_wakeup ↦ gensem thread_wakeup_spec

          ⊕ pt_in ↦ primcall_general_compatsem´ ptin_spec (prim_ident:= pt_in)
          ⊕ pt_out ↦ primcall_general_compatsem´ ptout_spec (prim_ident:= pt_out)
          ⊕ container_get_quota ↦ gensem container_get_quota_spec
          ⊕ container_get_usage ↦ gensem container_get_usage_spec
          ⊕ container_can_consume ↦ gensem container_can_consume_spec
          ⊕ trap_in ↦ primcall_general_compatsem trapin_spec
          ⊕ trap_out ↦ primcall_general_compatsem trapout_spec
          ⊕ host_in ↦ primcall_general_compatsem hostin_spec
          ⊕ host_out ↦ primcall_general_compatsem hostout_spec
          ⊕ trap_get ↦ primcall_trap_info_get_compatsem trap_info_get_spec
          ⊕ trap_set ↦ primcall_trap_info_ret_compatsem trap_info_ret_spec

          ⊕ thread_yield ↦ primcall_thread_schedule_compatsem thread_yield_spec (prim_ident:= thread_yield)
          ⊕ thread_sleep ↦ primcall_thread_transfer_compatsem thread_sleep_spec

          ⊕ cli ↦ gensem cli_spec
          ⊕ sti ↦ gensem sti_spec
          ⊕ cons_buf_read ↦ gensem cons_buf_read_spec
          ⊕ serial_putc ↦ gensem serial_putc_spec
          ⊕ serial_intr_disable ↦ gensem serial_intr_disable_spec
          ⊕ serial_intr_enable ↦ gensem serial_intr_enable_spec

          ⊕ accessors ↦ {| exec_load := @exec_loadex; exec_store := @exec_storeex |}.

  Definition pipc : compatlayer (cdata RData) := pipc_fresh ⊕ pipc_passthrough.


End WITHMEM.