Require Import Coqlib.
Require Import Maps.
Require Import ASTExtra.
Require Import Integers.
Require Import Floats.
Require Import Values.
Require Import Memory.
Require Import Events.
Require Import Stacklayout.
Require Import Globalenvs.
Require Import AsmX.
Require Import Smallstep.
Require Import AuxStateDataType.
Require Import Constant.
Require Import GlobIdent.
Require Import FlatMemory.
Require Import CommonTactic.
Require Import AuxLemma.
Require Import RealParams.
Require Import PrimSemantics.
Require Import LAsm.
Require Import LoadStoreSem1.
Require Import ObservationImpl.

Require Import liblayers.logic.PTreeModules.
Require Import liblayers.logic.LayerLogicImpl.
Require Import liblayers.compat.CompatLayers.
Require Import liblayers.compat.CompatGenSem.

Require Import INVLemmaMemory.
Require Import INVLemmaContainer.

Require Import AbstractDataType.

Require Export ObjCPU.
Require Export ObjPMM.
Require Export ObjFlatMem.
Require Export ObjContainer.

Section WITHMEM.

  Local Open Scope Z_scope.

  Context `{real_params: RealParams}.

  Record high_level_invariant (abd: RData) :=
    mkInvariant {
        valid_nps: init abd = true → kern_low ≤ nps abd ≤ maxpage;
        valid_kern: ikern abd = false → pg abd = true ∧ init abd = true;
        valid_AT_kern: init abd = true → AT_kern (AT abd) (nps abd);
        valid_AT_usr: init abd = true → AT_usr (AT abd) (nps abd);
        valid_ihost: ihost abd = false → pg abd = true ∧ init abd = true ∧ ikern abd = true;
        valid_pperm: consistent_ppage (AT abd) (pperm abd) (nps abd);
        init_pperm: init abd = false → (pperm abd) = ZMap.init PGUndef;
        valid_container: Container_valid (AC abd);
        valid_preinit_container:
          init abd = false →
          ∀ x, 0 ≤ x < num_id → cused (ZMap.get x (AC abd)) ≠ true;
        valid_quota_bounded: quota_bounded_AT (AC abd) (AT abd) (nps abd)
    }.

  Global Instance mcontainer_data_ops : CompatDataOps RData :=
    {
      empty_data := init_adt;
      high_level_invariant := high_level_invariant;
      low_level_invariant := low_level_invariant;
      kernel_mode adt := ikern adt = true ∧ ihost adt = true;
      observe := ObservationImpl.observe
    }.

  Section Property_Abstract_Data.

    Lemma empty_data_high_level_invariant:
      high_level_invariant init_adt.
    Proof.
      constructor; auto; simpl; try discriminate 1.
      - apply consistent_ppage_init.
      - apply empty_container_valid.
      - intros; simpl; rewrite ZMap.gi; discriminate.
    Qed.

    Global Instance mcontainer_data_prf : CompatData RData.
    Proof.
      constructor.
      - apply low_level_invariant_incr.
      - apply empty_data_low_level_invariant.
      - apply empty_data_high_level_invariant.
    Qed.

  End Property_Abstract_Data.

  Context `{Hstencil: Stencil}.
  Context `{Hmem: Mem.MemoryModel}.
  Context `{Hmwd: UseMemWithData mem}.

  Section INV.

    Global Instance container_init_inv: PreservesInvariants container_init_spec.
    Proof.
      preserves_invariants_simpl low_level_invariant high_level_invariant.
      - apply real_nps_range.
      - apply real_at_kern_valid.
      - apply real_at_usr_valid.
      - rewrite init_pperm0; try assumption.
        apply real_pperm_valid.
      - apply real_container_valid.
      - apply real_quota_bounded_AT.
    Qed.

    Global Instance container_split_inv: PreservesInvariants container_split_spec.
    Proof.
      preserves_invariants_simpl low_level_invariant high_level_invariant; auto.
      exploit split_container_valid; eauto.
      subst c; contradiction (valid_preinit_container0 H (Int.unsigned i)).
      inv valid_container0; auto.
      apply split_quota_bounded_AT in H2; auto.
    Qed.

    Section CONTAINER_ALLOC.

      Lemma container_alloc_high_level_inv:
        ∀ d d' i n,
          container_alloc_spec i d = Some (d', n) →
          high_level_invariant d →
          high_level_invariant d'.
      Proof.
        intros. functional inversion H; subst c; try subst c0; subst; eauto.
        inv H0. constructor; simpl; eauto; try congruence.
        - intros; eapply AT_kern_norm'; eauto.
        - intros; eapply AT_usr_norm; eauto.
        - eapply consistent_ppage_norm_alloc; eauto.
        - eapply alloc_container_valid'; eauto.
        - apply container_alloc_quota_bounded_AT in H; auto.
      Qed.

      Lemma container_alloc_low_level_inv:
        ∀ d d' n n' i,
          container_alloc_spec i d = Some (d', n) →
          low_level_invariant n' d →
          low_level_invariant n' d'.
      Proof.
        intros. functional inversion H; subst c; try subst c0; subst; eauto.
        inv H0. constructor; eauto.
      Qed.

      Lemma container_alloc_kernel_mode:
        ∀ d d' i n,
          container_alloc_spec i d = Some (d', n) →
          kernel_mode d →
          kernel_mode d'.
      Proof.
        intros. functional inversion H; subst c; try subst c0; subst; eauto.
      Qed.

      Global Instance container_alloc_inv: PreservesInvariants container_alloc_spec.
      Proof.
        preserves_invariants_simpl'.
        - eapply container_alloc_low_level_inv; eassumption.
        - eapply container_alloc_high_level_inv; eassumption.
        - eapply container_alloc_kernel_mode; eassumption.
      Qed.

    End CONTAINER_ALLOC.

    Global Instance pfree'_inv: PreservesInvariants pfree'_spec.
    Proof.
      preserves_invariants_simpl low_level_invariant high_level_invariant; auto.
      - intros; eapply AT_kern_norm; eauto.
      - intros; eapply AT_usr_norm; eauto.
      - eapply consistent_ppage_norm_undef; eauto.
      - apply pfree_quota_bounded_AT; auto.
    Qed.

    Global Instance setPG_inv: PreservesInvariants setPG0_spec.
    Proof.
      preserves_invariants_simpl low_level_invariant high_level_invariant; auto.
    Qed.

    Global Instance clearCR2_inv: PreservesInvariants clearCR2_spec.
    Proof.
      preserves_invariants_simpl low_level_invariant high_level_invariant; auto.
    Qed.

    Global Instance setCR3_inv: SetCR3Invariants setCR30_spec.
    Proof.
      constructor; intros.
      - functional inversion H; inv H0; constructor; trivial.
      - functional inversion H; inv H0; constructor; auto.
      - functional inversion H; simpl in *; assumption.
    Qed.

    Global Instance set_at_c_inv: PreservesInvariants set_at_c0_spec.
    Proof.
      preserves_invariants_simpl low_level_invariant high_level_invariant; auto.
      - intros; eapply AT_kern_norm; eauto.
      - intros; eapply AT_usr_norm; eauto.
      - eapply consistent_ppage_norm; eauto.
      - unfold quota_bounded_AT in *; rewrite unused_pages_AT_set; cases; omega.
    Qed.

    Global Instance device_output_inv: PreservesInvariants device_output_spec.
    Proof.
      preserves_invariants_simpl'' low_level_invariant high_level_invariant; eauto.
    Qed.

    Global Instance trapin_inv: PrimInvariants trapin_spec.
    Proof.
      PrimInvariants_simpl H H0.
    Qed.

    Global Instance trapout_inv: PrimInvariants trapout0_spec.
    Proof.
      PrimInvariants_simpl H H0.
    Qed.

    Global Instance hostin_inv: PrimInvariants hostin_spec.
    Proof.
      PrimInvariants_simpl H H0.
    Qed.

    Global Instance hostout_inv: PrimInvariants hostout_spec.
    Proof.
      PrimInvariants_simpl H H0.
    Qed.

    Global Instance fstore_inv: PreservesInvariants fstore0_spec.
    Proof.
      preserves_invariants_simpl low_level_invariant high_level_invariant; trivial;
      functional inversion H; subst; auto.
    Qed.

    Global Instance flatmem_copy_inv: PreservesInvariants flatmem_copy0_spec.
    Proof.
      preserves_invariants_simpl low_level_invariant high_level_invariant; eauto.
    Qed.

  End INV.

  Definition exec_loadex {F V} := exec_loadex1 (F := F) (V := V).

  Definition exec_storeex {F V} := exec_storeex1 (flatmem_store:= flatmem_store) (F := F) (V := V).

  Global Instance flatmem_store_inv: FlatmemStoreInvariant (flatmem_store:= flatmem_store).
  Proof.
    split; inversion 1; intros.
    - functional inversion H0; constructor; auto.
    - functional inversion H1; constructor; auto.
  Qed.

  Global Instance trapinfo_set_inv: TrapinfoSetInvariant.
  Proof.
    split; inversion 1; intros; constructor; auto.
  Qed.

  Definition mcontainer_fresh : compatlayer (cdata RData) :=
    container_init ↦ gensem container_init_spec
           ⊕ container_get_parent ↦ gensem container_get_parent_spec
           ⊕ container_get_nchildren ↦ gensem container_get_nchildren_spec
           ⊕ container_get_quota ↦ gensem container_get_quota_spec
           ⊕ container_get_usage ↦ gensem container_get_usage_spec
           ⊕ container_can_consume ↦ gensem container_can_consume_spec
           ⊕ container_split ↦ gensem container_split_spec

           ⊕ container_alloc ↦ gensem container_alloc_spec.

  Definition mcontainer_passthrough: compatlayer (cdata RData) :=
    fload ↦ gensem fload'_spec
          ⊕ fstore ↦ gensem fstore0_spec
          ⊕ flatmem_copy ↦ gensem flatmem_copy0_spec
          ⊕ vmxinfo_get ↦ gensem vmxinfo_get_spec
          ⊕ device_output ↦ gensem device_output_spec
          ⊕ set_pg ↦ gensem setPG0_spec
          ⊕ pfree ↦ gensem pfree'_spec
          ⊕ clear_cr2 ↦ gensem clearCR2_spec
          ⊕ set_cr3 ↦ setCR3_compatsem setCR30_spec
          ⊕ at_get_c ↦ gensem get_at_c_spec
          ⊕ at_set_c ↦ gensem set_at_c0_spec
          ⊕ trap_in ↦ primcall_general_compatsem trapin_spec
          ⊕ trap_out ↦ primcall_general_compatsem trapout0_spec
          ⊕ host_in ↦ primcall_general_compatsem hostin_spec
          ⊕ host_out ↦ primcall_general_compatsem hostout_spec
          ⊕ trap_get ↦ primcall_trap_info_get_compatsem trap_info_get_spec
          ⊕ trap_set ↦ primcall_trap_info_ret_compatsem trap_info_ret_spec
          ⊕ accessors ↦ {| exec_load := @exec_loadex; exec_store := @exec_storeex |}.

  Definition mcontainer : compatlayer (cdata RData) := mcontainer_fresh ⊕ mcontainer_passthrough.

End WITHMEM.